AsyncQuoteSubmit Class

AsyncQuoteSubmit.InitializeSettings Class Properties 

The AsyncQuoteSubmit.InitializeSettings class includes the following global properties.

AsyncQuoteSubmit.InitializeResponse Class Properties 

The AsyncQuoteSubmit.InitializeResponse class includes the following global properties.

Initialize a Draft Order for a Quote

public void initializeHighVolumeQuote(Id highVolumeQuoteId) {
    zqu.AsyncQuoteSubmit.InitializationSettings initializationSettings = new zqu.AsyncQuoteSubmit.InitializationSettings();
    initializationSettings.quoteId = highVolumeQuoteId;
    zqu.AsyncQuoteSubmit.InitializationResponse initializationResponse = zqu.AsyncQuoteSubmit.initialize(initializationSettings);
    zqu__Quote__c highVolumeQuote = [
        SELECT Id, zqu__AsyncDraftOrderId__c, zqu__AsyncDraftSubscriptionId__c
        FROM zqu__Quote__c
        WHERE Id = :highVolumeQuoteId LIMIT 1
    ];
    System.assertEquals(initializationResponse.orderId, highVolumeQuote.zqu__AsyncDraftOrderId__c);
    System.assertEquals(initializationResponse.subscriptionId, highVolumeQuote.zqu__AsyncDraftSubscriptionId__c);
}

Add Actions to an Initialized Draft Order

public void addActions(Id highVolumeQuoteId, Set<Id> quoteAmendmentIds) {
    zqu.AsyncQuoteSubmit.AddActionsSettings addActionsSettings = new zqu.AsyncQuoteSubmit.AddActionsSettings();
    addActionsSettings.quoteId = highVolumeQuoteId;
    addActionsSettings.quoteAmendmentIds = quoteAmendmentIds;
    try {
        zqu.AsyncQuoteSubmit.AddActionsResponse addActionsResponse = zqu.AsyncQuoteSubmit.addActions(addActionsSettings);
    } catch (zqu.AsyncQuoteSubmit.AddActionsException addActionsException) {
        System.debug('Failed with message: ' + addActionsException.getMessage());
        System.debug('Failed to add Quote Amendment Id values: ' + addActionsException.getErrorQuoteAmendmentIds());
    }
}

Initialize a Preview for a Draft Order after Actions have been Added

public void initializePreview(Id highVolumeQuoteId) {
    zqu.AsyncQuoteSubmit.PreviewSettings previewSettings = new zqu.AsyncQuoteSubmit.PreviewSettings();
    previewSettings.quoteId = highVolumeQuoteId;
    zqu.AsyncQuoteSubmit.PreviewResponse previewResponse = zqu.AsyncQuoteSubmit.preview(previewSettings);
    zqu__Quote__c highVolumeQuote = [
        SELECT Id, zqu__AsyncJobId__c
        FROM zqu__Quote__c
        WHERE Id = :highVolumeQuoteId LIMIT 1
    ];
    System.assertEquals(previewResponse.jobId, highVolumeQuote.zqu__AsyncJobId__c);
}

Retrieve Results for a Draft Order Where the Preview has been Initialized

// This method should be called from within a scheduled job, in order to have it re-run until process is complete
public void retrievePreviewResults(Id highVolumeQuoteId) {
    zqu.AsyncQuoteSubmit.PreviewResultSettings previewResultSettings = new zqu.AsyncQuoteSubmit.PreviewResultSettings();
    previewResultSettings.quoteId = highVolumeQuoteId;
    zqu.AsyncQuoteSubmit.PreviewResultResponse previewResultResponse = zqu.AsyncQuoteSubmit.previewResult(previewResultSettings);
    switch on previewResultResponse.status {
        when 'Initialized' {
            System.debug('Preview has been initialized.');
        }
        when 'Processing' {
            System.debug('Preview is currently being processed.');
            // If this is part of scheduled job, the job that calls this method should be rescheduled for a later time in order to check status again
        }
        when 'Failed' {
            System.debug('Process has failed.');
        }
        when 'Completed' {
            System.debug('Process has completed');
            // Check if there was an error
            if (previewResultResponse.errors != null) {
                System.debug(previewResultResponse.errors);
            } else {
                System.debug(previewResultResponse.result.invoices);
                System.debug(previewResultResponse.result.chargeMetrics);
            }
        }
        when else {
            System.debug('Process is in an unknown state');
        }
    }
}

Retrieve Preview Invoice Items for a Draft Order Where the Preview Job has Completed

// Retrieve Preview Invoice Items for completed preview job
public void retrievePreviewInvoiceItems(Id highVolumeQuoteId) {
    // This is an example where 12 * 1000 = 12,000 Invoice Items are expected
    zqu.AsyncQuoteSubmit.PreviewMetricsSettings previewMetricsSettings = new zqu.AsyncQuoteSubmit.PreviewMetricsSettings();
    previewMetricsSettings.quoteId = highVolumeQuoteId;
    // Skip records 0 - 999 (zero-based index)
    previewMetricsSettings.offset = 1000;
    // Retrieve records 1000 - 1999 (zero-based index)
    previewMetricsSettings.pageSize = 1000;
    zqu.AsyncQuoteSubmit.PreviewInvoiceItemsResponse previewInvoiceItemsResponse = zqu.AsyncQuoteSubmit.previewInvoiceItems(previewMetricsSettings);
    System.assertEquals(previewMetricsSettings.pageSize, previewInvoiceItemsResponse.count);
    // Should be true, since there are more records to go through
    System.assertEquals(true, previewInvoiceItemsResponse.hasMore);
    for (zqu.MetricsResult.InvoiceItem invoiceItem : previewInvoiceItemsResponse.metrics) {
        System.debug(invoiceItem);
    }
}

Retrieve Preview Charges for a Draft Order Where the Preview Job has Completed

// Retrieve Preview Charges for completed preview job
public void retrievePreviewCharges(Id highVolumeQuoteId) {
    // This is an example where 1000 charges exist under the quote
    zqu.AsyncQuoteSubmit.PreviewMetricsSettings previewMetricsSettings = new zqu.AsyncQuoteSubmit.PreviewMetricsSettings();
    previewMetricsSettings.quoteId = highVolumeQuoteId;
    // Skip records 0 - 249 (zero-based index)
    previewMetricsSettings.offset = 250;
    // Retrieve records 250 - 499 (zero-based index)
    previewMetricsSettings.pageSize = 250;
    zqu.AsyncQuoteSubmit.PreviewChargesResponse previewChargesResponse = zqu.AsyncQuoteSubmit.previewCharges(previewMetricsSettings);
    System.assertEquals(previewMetricsSettings.pageSize, previewChargesResponse.count);
    // Should be true, since there are more records to go through
    System.assertEquals(true, previewChargesResponse.hasMore);
    for (zqu.MetricsResult.Charge charge : previewChargesResponse.metrics) {
        System.debug(charge);
    }
}

Activate the Draft Order

public void activateDraftOrder(Id highVolumeQuoteId) {
    zqu.AsyncQuoteSubmit.ActivateSettings activateSettings = new zqu.AsyncQuoteSubmit.ActivateSettings();
    activateSettings.quoteId = highVolumeQuoteId;
    zqu.AsyncQuoteSubmit.ActivateResponse activateResponse = zqu.AsyncQuoteSubmit.activate(activateSettings);
}

 Retrieve activation results

// This method should be called from within a scheduled job, in order to have it re-run until process is complete
public void retrieveActivationResults(Id highVolumeQuoteId) {
    zqu.AsyncQuoteSubmit.ActivateResultSettings activateResultSettings = new zqu.AsyncQuoteSubmit.ActivateResultSettings();
    activateResultSettings.quoteId = highVolumeQuoteId;
    zqu.AsyncQuoteSubmit.ActivateResultResponse activateResultResponse = zqu.AsyncQuoteSubmit.activateResult(activateResultSettings);
    switch on activateResultResponse.status {
        when 'Initialized' {
            System.debug('Preview has been initialized.');
        }
        when 'Processing' {
            System.debug('Preview is currently being processed.');
            // If this is part of scheduled job, the job that calls this method should be rescheduled for a later time in order to check status again
        }
        when 'Failed' {
            System.debug('Process has failed.');
        }
        when 'Completed' {
            System.debug('Process has completed');
            if (activateResultResponse.errors != null) {
                System.debug(activateResultResponse.errors);
            } else {
                System.debug(activateResultResponse.result);
            }
        }
        when else {
            System.debug('Process is in an unknown state');
        }
    }
}